forum.hwkitchen.cz

Kód: Vybrat vše

//porty pro pripojeni tlacitek, tlacitko spina pin na zem
#define BUTT_A  9     
#define BUTT_B  10

enum whatcall_t{CALL_NONE, CALL_A, CALL_B, CALL_AB, CALL_BA};

whatcall_t  callFunc;

whatcall_t  CheckButtons(uint8_t portButtA, uint8_t portButtB, uint32_t samplePeriod);  //prototyp funkce 


void setup() {
  // put your setup code here, to run once:
  pinMode(BUTT_A, INPUT_PULLUP);
  pinMode(BUTT_B, INPUT_PULLUP);
}

void loop() {
  // neco tady muzu delat
  callFunc=CheckButtons(BUTT_A, BUTT_B, 50);
  // neco tady muzu delat
  switch(callFunc){
    case CALL_NONE:
    break;
    case CALL_A:
      //provadim akci pro stisk a pusteni tlac. A
    break;
    case CALL_B:
      //provadim akci pro stisk a pusteni tlac. B
    break;
    case CALL_AB:
      //provadim akci pro stisk tlac. A a nasledny stisk B
    break;
    case CALL_BA:
      //provadim akci pro stisk tlac. B a nasledny stisk A
    break;
  }
}

whatcall_t  CheckButtons(uint8_t portButtA, uint8_t portButtB, uint32_t samplePeriod){ 
                        //pin tlacitka A, pin tlacitka B, po kolika ms se bude samplovat a vyhodnocovat stav
  static  uint8_t     stage=0;
  static  uint32_t    nextTime=0;
          bool        buttA,buttB;
          whatcall_t  outVal=CALL_NONE;
  if(millis()<nextTime){
    return CALL_NONE;
  }
  nextTime=millis()+samplePeriod;
  if(digitalRead(portButtA)==LOW){
    buttA=true;
  }else{
    buttA=false;
  }
  if(digitalRead(portButtB)==LOW){
    buttB=true;
  }else{
    buttB=false;
  }
  switch(stage){
    case 0:
      if(buttA && (!buttB)){  //pouze A stisknuto
        stage=1;
      }else{
        if(buttB && (!buttA)){  //pouze B stisknuto
          stage=3;
        }      
      }
    break;   
    case 1:
      if((!buttA)&&(!buttB)){  //uvolneno A i B
        stage=0;
        outVal=CALL_A;
      }else{
        if(buttA && buttB){ //pridan stisk B
          stage=2;
          outVal=CALL_AB;
        }
      }
    break;   
    case 2:
      if((!buttA)&&(!buttB)){  //uvolneno A i B, prechod do zakladniho stavu
        stage=0;
      }
    break;    
    case 3:
      if((!buttA)&&(!buttB)){  //uvolneno A i B
        stage=0;
        outVal=CALL_B;
      }else{
        if(buttA && buttB){ //pridan stisk A
          stage=2;
          outVal=CALL_BA;
        }
      }
    break;    
   }
  return outVal;
}