forum.hwkitchen.cz

Kód: Vybrat vše

#define LED 13  //pin ledky

const unsigned int PERIOD=1000; //perioda blikani v ms
volatile bool LedBlink=false;

//------------- Function prototypes
ISR(TIMER2_COMPA_vect);  // obslouzeni interruptu od timeru 2 (kazdych 13us)



void setup() {
  pinMode(LED,OUTPUT);
// nastaveni timeru 2
  TCCR2A = bit(WGM21);          // nebude vystup na port a rezim bude CTC
  TCCR2B = bit(CS22)|bit(CS21)|bit(CS20);    // zdroj signalu Fosc a preddelic 1024, inkrementace 15625 za sec
  OCR2A =  155;                  // interrupt a znovunastaveni pri dosazeni stavu,int kazdych 155x64us=cca 10ms
  TIMSK2 = bit (OCIE2A);        // povoleni preruseni v masce interruptu
// END nastaveni timeru 2


}

void loop() {
  // put your main code here, to run repeatedly:
  LedBlink=true; //zapne blikani
  delay(14589); //neco delame 
  LedBlink=false;//vypne blikani
  delay(19722); //neco delame 
  
}

// Interruptt routine
ISR(TIMER2_COMPA_vect){  // obslouzeni interruptu od timeru 2 (kazdych cca10ms)
  static unsigned int Prescaler=0;
  static bool Toggle=true;
  static bool Set=true;
  if(LedBlink){  
    Set=true;
    Prescaler++;  //preddelic pro periodu 
    if(Prescaler>=(PERIOD/20)){
      Prescaler=0;
      if(Toggle){
        digitalWrite(LED,HIGH);
      }else{
        digitalWrite(LED,LOW);
      }
      Toggle=!Toggle; 
    }
  }else{
    if(Set){  //aby se nastavovalo jenom jednou
      digitalWrite(LED,LOW); //ledku musime vypnout, protoze nevime v jake fazi blikani prijde zakaz  
      Prescaler=0;
      Set=false;
    }
  }
  
}