Re: Mini CNC osa Z
Napsal: 27 lis 2019, 17:50
Úplně stejně jako řešíš to, aby ti diody blikaly bez delay.
Kód: Vybrat vše
#define TLACITKO 2 // číslo pinu TLACITKA
#define LED1 10 // číslo pinu LED1 zelená
#define LED2 11 // číslo pinu LED2 červená
boolean buttonState = false; //nejnovější hodnota načtená ze vstupního pinu
boolean lastButtonState = false; // předchozí hodnota načtení ze vstupního pinu
boolean lastTrueButtonState = false; // předchozí hodnota ošetřeného tlačítka
// Následné proměnné jsou typu long, jelikož čas měřený v milisekundách se
//rychle změní na větší číslo, jež nemůže být uloženo v int
unsigned long lastDebounceTime = 0; // čas posledního změny výstupního pinu
unsigned long debounceDelay = 50; // čas debounce prodlevy
byte mode = 0; // 0 - Vypnuto, 1 - Zapnuto, 2 - Blikání rychlé, 3 - Blikání pomalé, 4 - Blikání střídavé
unsigned long aktualniMillis; //aktualní čas
unsigned long predchoziMillis1; // předchozí čas pro rychle blikání
unsigned long predchoziMillis2; // předchozí čas pro pomalé blikání
unsigned long predchoziMillis3; // předchozí čas pro střídavé blikání
unsigned long cas = 0;
long buttonTime; // čas začátku stisknutí tlačítka
boolean led1svetlo; // pomocná proměnná led1svetlo
boolean led2svetlo; // pomocná proměnná led2svetlo
void setup() {
pinMode(LED1, OUTPUT); // pin pro LED1 nastaven jako výstup
pinMode(LED2, OUTPUT); // pin pro LED2 nastaven jako výstup
pinMode(TLACITKO, INPUT); // pin pro TLACITKO nastaveno jako vstup
Serial.begin(9600); // konfigurace rychlosti seriového portu
while (!Serial) { ; // čekaní na připojení seriového portu, pry nezbytné pouze u desky Leonardo
}
Serial.println("Seriovy port aktivni"); // První výpis na seriový port
}
void loop(){
/*TOHLE JE ZAČÁTEK BLOKU KDE OŠETŘUJI TLAČÍTKO*/
buttonState = digitalRead(TLACITKO); // přečtení stavu tlačítka
if (buttonState != lastButtonState) { // kmita to, od minule se to zmenilo, zacnu debounce cas pocitat znovu (tedy od posledni zmeny, ktera je ted)
lastDebounceTime = millis();
}
if ((millis() - lastDebounceTime) > debounceDelay) { // jo, uz se to dlouho nezmenilo, tak je to stabilni a spravna hodnota
if (buttonState != lastTrueButtonState) { // Pokud se stav tlačítka změnil tj. porovná se buttonState (stav tlačítka) s předchozím stavem
if(buttonState == true) {
mode++; // přičte k MODE hodnotu 1
buttonTime = millis();
if (mode > 4) mode = 0; // když je mode větší jak 4 tak ho vynuluje
}
lastTrueButtonState = buttonState; // uložím si nový pravý ošetřený stav tlačítka
}
}
lastButtonState = buttonState; // tady si to ulozim, v dalsim pruchodu loop() to zase porovnam s novym stavem, zda se to mezi tim nezmenilo
if(mode == 0) {
// ******* LED1, LED2 vypnuto ********
led1svetlo = false; // zhasni LED1
led2svetlo = false; // zhasni LED2
if(millis() >= cas + 1000){
cas = millis();
Serial.println("LED1,LED2 vypnuto"); // výpis na seriový monitor
}
}
if(mode == 1) {
// ******* LED1, LED2 zapnuto ********
led1svetlo = true; // rožni LED1
led2svetlo = true; // rožni LED2
if(millis() >= cas + 1000){
cas = millis();
Serial.println("LED1,LED2 zapnuto"); // výpis na seriový monitor
}
}
if(mode == 2){
// ******* LED1,LED2 blikání rychlé *******
if(millis() - buttonTime > 10000){ // zjistím si jestli je čas něco provést, uběhlo už 10s od poslední akce?
if(millis() >= cas + 400){
cas = millis();
Serial.println("LED1,LED2 blikání rychlé"); // výpis na seriový monitor
}
aktualniMillis = millis(); // podívám se na hodinky - aktuální čas
if(aktualniMillis - predchoziMillis1 > 200) { // nejprve si zjistím jestli je čas něco provést, uběhlo už 200ms od poslední akce?
if (led1svetlo) {
led1svetlo = false; // zhasnu LED1
led2svetlo = false; // zhasnu LED2
} else {
led1svetlo = true; // rožnu LED1
led2svetlo = true; // rožnu LED2
}
predchoziMillis1 = aktualniMillis; // v tento čas jsem provedl poslední akci
}
} else {
//vypis : "do bliknutí zbývá ..... ms" - jestli chci vědět jak dlouho budu ještě čekat vypíšu 10000 - (millis() - buttonTime)
Serial.print(" blikání za ");
Serial.print(10000 - (millis() - buttonTime));
Serial.println(" ms");
}
}
if(mode == 3) {
// ******* LED1,LED2 blikání pomalé *******
aktualniMillis = millis(); //podívám se na hodinky - aktuální čas
if(aktualniMillis - predchoziMillis2 > 500) { // nejprve si zjistím jestli je čas něco provést, uběhlo už 500ms od poslední akce?
if (led2svetlo) {
led1svetlo = false; // zhasnu LED1
led2svetlo = false; // zhasnu LED2
} else {
led1svetlo = true; // rožnu LED1
led2svetlo = true; // rožnu LED2
}
predchoziMillis2 = aktualniMillis; // v tento čas jsem provedl poslední akci
}
if(millis() >= cas + 1000){
cas = millis();
Serial.println("LED1,LED2 blikání pomalé"); // výpis na seriový monitor
}
}
if(mode == 4) {
// ******* LED1,LED2 blikání střídavé *******
aktualniMillis = millis(); //podívám se na hodinky - aktuální čas
if(aktualniMillis - predchoziMillis3 > 300) { // nejprve si zjistím jestli je čas něco provést, uběhlo už 300ms ?
led1svetlo = !led1svetlo; // do proměnné led1svetlo zapíšu její negovanou hodnotu, tj. svítila-li LED1 tak zhasne, byla-li zhaslá rožne se
led2svetlo = !led1svetlo; // do proměnné led2svetlo zapíšu negovanou hodnotu led1svetlo, tj. pokud LED1 svítí chci LED2 zhaslou a naopak
predchoziMillis3 = aktualniMillis; // v tento čas jsem provedl poslední akci
Serial.println("LED1,LED2 blikání střídavé"); // výpis na seriový monitor
}
}
digitalWrite(LED1,led1svetlo); // aktualizace stavu LED1, zápis proměnné led1svetlo na výstupní pin 10
digitalWrite(LED2,led2svetlo); // aktualizace stavu LED2, zápis proměnné led2svetlo na výstupní pin 11
}mám velkou radost děkuju
bohužel nemám připomínky na čem ověřit, i proto tenhle dotaz