Prosím o pomoc, zapojeni+kód (nema23)

[bernkop]

Dobrý den,
Prosím o radu jak zapojit tuto sestavu viz foto. Jedna se mi pouze o manuální ovládání přes joystick. Byl bych moc rad kdyby mi někdo poradil jak zapojit (schéma), napsal kód (joystick v levo/pravo 1.moror nahoru/dolu 2.motor stlačení “tlačítka” otočení serva o 30 stupňů.) děkuji moc za odpověď

[AstroMiK]

Jsem teď na služebce, takže to nemám jak vyzkoušet, ale upravil jsem ten původní program na motorové ostření dalekohledu, na který jsem odkazoval v předchozím vlákně ( viewtopic.php?f=37&t=1827 ).

Teď by se mělo krátkým nahnutím joysticku do boku krokovat prvním motorem po jednom kroku a delším nakloněním (nad 1 sekundu) by se mělo krokovat automaticky.
Nahoru a dolu platí to samé, akorát pro druhý krokový motor.

Popis připojovacích pinů je v programu.


Ještě upřesni, co má dělat to tlačítko na joysticku.
Když se stiskne, tak se servo otočí o 30° a když se uvolní, tak se vrátí zpátky na 0°?
Nebo po uvolnění tlačítka zůstane servo na 30°?

Kód: Vybrat vše

//-----------------------------------------------------------
// Ovladani krokoveho motoru pomoci joysticku pres DRV8255
//       vlevo  / vpravo  .... prvni motor (osa X) - Krokovani po jednotlivych krocich (po kazdem kroku se musi joystick narovnat).
//                             Kdyz bude joystick vychyleny vlevo nebo vpravo delsi dobu nez 1 sekundu, bude se krokovat automaticky.
//
//       nahoru  / dolu   .... druhy motor (osa Y) - Krokovani po jednotlivych krocich (po kazdem kroku se musi joystick narovnat).
//                             Kdyz bude joystick vychyleny nahoru nebo dolu delsi dobu nez 1 sekundu, bude se krokovat automaticky.
//
//-----------------------------------------------------------



//----------------------------------
//  prirazeni pinu
#define pin_X              A0                 // joystick - osa X
#define pin_Y              A1                 // joystick - osa Y

#define motor_X_STEP        4                 // impulzni vstup X_DRV8255
#define motor_X_DIR         5                 // smerovy vstup X_DRV8255

#define motor_Y_STEP        6                 // impulzni vstup Y_DRV8255
#define motor_Y_DIR         7                 // smerovy vstup Y_DRV8255



#define automaticky_krok   50                 // jak dlouha pauza ma byt pri delsim vychyleni joysticku (nastaveni rychlosti automatickeho krokovani)

//----------------------------------
// globalni promenne
unsigned int osa_X;                           // analogova hodnota vychyleni joysticku pro osu X
unsigned int osa_Y;                           // analogova hodnota vychyleni joysticku pro osu Y

boolean odblokovano_X = true;                 // blokovani pro jednotlive kroky v ose X
boolean odblokovano_Y = true;                 // blokovani pro jednotlive kroky v ose Y

unsigned long casovac;                        // odpocet dlouheho nakloneni joysticku


//----------------------------------
//  nastaveni smeru pinu
void setup(void)
  {
    Serial.begin(9600);

    pinMode(pin_X, INPUT);
    pinMode(pin_Y, INPUT); 

    pinMode(motor_X_STEP, OUTPUT); 
    pinMode(motor_X_DIR, OUTPUT); 

    pinMode(motor_Y_STEP, OUTPUT); 
    pinMode(motor_Y_DIR, OUTPUT); 
  }



//----------------------------------
//  hlavni smycka
void loop(void)
  {
    
    osa_X = analogRead(pin_X);                // v kazde smycce se zmeri napeti na obou osach
    osa_Y = analogRead(pin_Y);



//     Serial.print("        osa X: ");   // test funkce joysticku (jen kdyby neco nefungovalo)
//     Serial.print(osa_X);
//     Serial.print("        osa Y: ");
//     Serial.println(osa_Y);


    // ---------   vyhodnoceni X osy --------------
    if (osa_X > 200 and osa_X < 800)          // osa X neni vychylena
      {
        odblokovano_X = true;                 // v teto poloze se odblokuje jeden krok na motoru
      }

    if (osa_X < 100 and odblokovano_X == true)  // naklon joysticku vlevo
      {
        krok_X_minus();
        odblokovano_X = false;                // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                   // zaznam casu nakloneni
      }

    if (osa_X < 100 and (millis()-casovac) > 1000)  // naklon joysticku vlevo trva uz dele nez sekundu
      {
        krok_X_minus();
        delay(automaticky_krok);
      }

    if (osa_X > 900 and odblokovano_X == true)  // naklon joysticku vpravo
      {
        krok_X_plus();
        odblokovano_X = false;                  // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                   // zaznam casu nakloneni
      }

    if (osa_X > 900 and (millis()-casovac) > 1000)  // naklon joysticku vpravo trva uz dele nez sekundu
      {
        krok_X_plus();
        delay(automaticky_krok);
      }


    // ---------   vyhodnoceni Y osy --------------
    if (osa_Y > 200 and osa_Y < 800)          // osa Y neni vychylena
      {
        odblokovano_Y = true;                   // v teto poloze se odblokuje jeden krok na motoru
      }

    if (osa_Y < 100 and odblokovano_Y == true) // naklon joysticku dolu
      {
        krok_Y_minus();
        odblokovano_Y = false;                  // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                   // zaznam casu nakloneni
      }

    if (osa_Y < 100 and (millis()-casovac) > 1000)  // naklon joysticku dolu trva uz dele nez sekundu
      {
        krok_Y_minus();
        delay(automaticky_krok);
      }

    if (osa_Y > 900 and odblokovano_Y == true)  // naklon joysticku nahoru
      {
        krok_Y_plus();
        odblokovano_Y = false;                  // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                   // zaznam casu nakloneni
      }

    if (osa_Y > 900 and (millis()-casovac) > 1000)  // naklon joysticku nahoru trva uz dele nez sekundu
      {
        krok_Y_plus();
        delay(automaticky_krok);
      }
  
  }
//-------------- konec hlavni smycky --------------------



//----------------------------------
//  pootoceni motoru v ose X o jeden krok dopredu
void krok_X_plus(void)
  {
    digitalWrite(motor_X_DIR,HIGH);
    digitalWrite(motor_X_STEP,HIGH);
    delay(10);
    digitalWrite(motor_X_STEP,LOW);
    delay(10);    
  }



//----------------------------------
//  pootoceni motoru v ose X o jeden krok dozadu
void krok_X_minus(void)
  {
    digitalWrite(motor_X_DIR,LOW);
    digitalWrite(motor_X_STEP,HIGH);
    delay(10);
    digitalWrite(motor_X_STEP,LOW);
    delay(10);        
  }



//----------------------------------
//  pootoceni motoru v ose Y o jeden krok dopredu
void krok_Y_plus(void)
  {
    digitalWrite(motor_Y_DIR,HIGH);
    digitalWrite(motor_Y_STEP,HIGH);
    delay(10);
    digitalWrite(motor_Y_STEP,LOW);
    delay(10);    
  }



//----------------------------------
//  pootoceni motoru v ose Y o jeden krok dozadu
void krok_Y_minus(void)
  {
    digitalWrite(motor_Y_DIR,LOW);
    digitalWrite(motor_Y_STEP,HIGH);
    delay(10);
    digitalWrite(motor_Y_STEP,LOW);
    delay(10);        
  }

[bernkop]

děkuji moc za odpověď!! Chci se jen předem omluvit jsme v zapojovaní "kodovaním" a vše kolem toho absolutně mimo!!! nic méně to servo na klik o 30 st pohnout a po uvolnění vrátit z5 na 0

[AstroMiK]

To servo doplním, až se někdy dostanu domů...

Zatím můžeš zkusit ty motory a joystick.

Neznám přesně ten driver pro motory, takže raději použij nějaký katalogový list, ale myslím, že by to mělo být takhle:
Arduino GND - DIR minus - PUL minus - ENA minus
Arduino D4 - PUL plus (ale nevím, jestli není nutné ještě zařadit do série nějaký odpor)
Arduino D5 - DIR plus (zase nevím, jestli není nutný odpor v sérii)
Arduino 5V - pravděpodobně ENA plus (a opět nevím, jestli tam nemusí být odpor)

To samé pak pro druhý driver, akorát piny D4 a D5 se nahradi za D6 a D7.

A nakonec připojení joysticku:
Joystick GND - Arduino GND
Joystick 5V - Arduino 5V
Joystick X - Arduino A0
Joystick Y - Arduino A1

[AstroMiK]

Přikládám upravený program, ve kterém je začleněno i to servo.

S tím konkrétním driverem neporadím - neznám ho a ani k němu nemohu najít potřebnou dokumentaci.
Tam bych asi žádal radu od někoho, kdo s tím má praktickou zkušenost.

Můj program jen posílá na jednom pinu impulzy a na druhém pinu směr (a to celé 2x).

Ukázkové video je tady:
https://youtu.be/h3l7Mc77z7U

Bílé LED jsou impulzy a zelené LED směry jednotlivých krokových motorů.

Na videu je to blbě vidět, ale při delším vychýlení joysticku příslušná bílá LED normálně rychle bliká.
Na videu to vypadá jako by trvale svítila a občas zhasla.



EDIT:
Připojení ovládacího pinu serva je nastaveno na D9 na Arduinu a tlačítko joysticku je připojeno na pin D8 na Arduinu.

Kód: Vybrat vše

//-----------------------------------------------------------
// Ovladani krokoveho motoru pomoci joysticku pres DRV8255
//       vlevo  / vpravo  .... prvni motor (osa X) - Krokovani po jednotlivych krocich (po kazdem kroku se musi joystick narovnat).
//                             Kdyz bude joystick vychyleny vlevo nebo vpravo delsi dobu nez 1 sekundu, bude se krokovat automaticky.
//
//       nahoru  / dolu   .... druhy motor (osa Y) - Krokovani po jednotlivych krocich (po kazdem kroku se musi joystick narovnat).
//                             Kdyz bude joystick vychyleny nahoru nebo dolu delsi dobu nez 1 sekundu, bude se krokovat automaticky.
//
//       stisk tlacitka na joysticku najede servem do jedne nastavene polohy (parametr 'servo_ON')
//       uvolneni tlacitka na joysticku vrati servo do druhe nastavene polohy (parametr 'servo_OFF')
//       rychlost pohybu serva je nastavitelna (parametr 'rychlost_serva') 
//
// video: https://youtu.be/h3l7Mc77z7U
//-----------------------------------------------------------


#include <Servo.h>                                                       // knihovna pro ovladani serva
Servo servo1;

//----------------------------------
//  prirazeni pinu
#define pin_X              A0                                            // joystick - osa X
#define pin_Y              A1                                            // joystick - osa Y

#define motor_X_STEP        4                                            // impulzni vstup X_DRV8255
#define motor_X_DIR         5                                            // smerovy vstup X_DRV8255

#define motor_Y_STEP        6                                            // impulzni vstup Y_DRV8255
#define motor_Y_DIR         7                                            // smerovy vstup Y_DRV8255

#define joystick_tl         8                                            // tlacitko na joysticku (vnitrne se spina proti GND)
#define pin_servo           9                                            // ovladaci pin serva



//----------------------------------
//  konstantni parametry
#define automaticky_krok   50                                            // jak dlouha pauza ma byt pri delsim vychyleni joysticku (nastaveni rychlosti automatickeho krokovani)

#define servo_ON           90                                            // krajni poloha serva pri stisknutem tlacitku (rozsah 0 az 180)
#define servo_OFF         180                                            // krajni poloha serva pri uvolnenem tlacitku  (rozsah 0 az 180) 
#define rychlost_serva     50                                            // jakou rychlosti ma servo prejizdet (mensi cislo je rychlejsi prejezd)

//----------------------------------
// globalni promenne
unsigned int osa_X;                                                      // analogova hodnota vychyleni joysticku pro osu X
unsigned int osa_Y;                                                      // analogova hodnota vychyleni joysticku pro osu Y

boolean odblokovano_X = true;                                            // blokovani pro jednotlive kroky v ose X
boolean odblokovano_Y = true;                                            // blokovani pro jednotlive kroky v ose Y

unsigned long casovac;                                                   // odpocet dlouheho nakloneni joysticku

int uhel;                                                                // aktualni uhel serva
int smer_serva;                                                          // pricitani nebo odecitani jednicky pri pohybu serva (v zavislosti na tom, jestli je klidova poloha mensi nebo vetsi nez aktivni)
int cil;                                                                 // na jakou polohu se ma servo natocit (servo_ON nebo servo_OFF)
unsigned long posledni_zmena;                                            // casova znacka pro cas posledniho pootoceni serva o 1 stupen

//----------------------------------
void setup(void)
  {
    Serial.begin(9600);

    //  nastaveni smeru pinu
    pinMode(pin_X, INPUT);
    pinMode(pin_Y, INPUT); 

    pinMode(motor_X_STEP, OUTPUT); 
    pinMode(motor_X_DIR, OUTPUT); 

    pinMode(motor_Y_STEP, OUTPUT); 
    pinMode(motor_Y_DIR, OUTPUT); 

    pinMode(joystick_tl, INPUT_PULLUP);

    servo1.attach(pin_servo);
    servo1.write(servo_OFF);                                             // natoceni serva do klidove polohy
    uhel = servo_OFF;                                                    // do stejne polohy se nastavi i promenna 'uhel'
  }



//----------------------------------
//  hlavni smycka
void loop(void)
  {
    
    osa_X = analogRead(pin_X);                                           // v kazde smycce se zmeri napeti na obou osach
    osa_Y = analogRead(pin_Y);

    if (digitalRead(joystick_tl) == LOW)       cil = servo_ON;           // tlacitko na joysticku je stisknute (cilovy uhel se nastavi na polohu 'servo_OFF')
    else                                       cil = servo_OFF;          // tlacitko na joysticku je uvolnene  (cilovy uhel se nastavi na polohu 'servo_ON')
      

    if ((uhel != cil) and ((millis() - posledni_zmena) > rychlost_serva))// se servem se otaci jen v pripade, ze se aktualni 'uhel' a 'cil' neshoduje. Jinak je servo v klidu
      {                                                                  //         Otaceni je mozne ale az po vyprseni nastaveneho intervalu
        if (uhel > cil)   uhel --;                                       // vypocet noveho uhlu natoceni serva
        else              uhel ++;

        servo1.write(uhel);                                              // otoceni serva na nove vypocteny uhel
        
        posledni_zmena = millis();                                       // nova znacka pro dalsi porovnani s pozadovanym casovym intervalem mezi krokovanim serva
      }


//     Serial.print("cil serva: ");                                      // test funkce joysticku (jen kdyby neco nefungovalo)
//     Serial.print(cil);
//     Serial.print("        osa X: ");                                  
//     Serial.print(osa_X);
//     Serial.print("        osa Y: ");
//     Serial.println(osa_Y);


    // ---------   vyhodnoceni X osy --------------
    if (osa_X > 200 and osa_X < 800)                                     // osa X neni vychylena
      {
        odblokovano_X = true;                                            // v teto poloze se odblokuje jeden krok na motoru
      }

    if (osa_X < 100 and odblokovano_X == true)                           // naklon joysticku vlevo
      {
        krok_X_minus();
        odblokovano_X = false;                                           // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                                              // zaznam casu nakloneni
      }

    if (osa_X < 100 and (millis()-casovac) > 1000)                       // naklon joysticku vlevo trva uz dele nez sekundu
      {
        krok_X_minus();
        delay(automaticky_krok);
      }

    if (osa_X > 900 and odblokovano_X == true)                           // naklon joysticku vpravo
      {
        krok_X_plus();
        odblokovano_X = false;                                           // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                                              // zaznam casu nakloneni
      }

    if (osa_X > 900 and (millis()-casovac) > 1000)                       // naklon joysticku vpravo trva uz dele nez sekundu
      {
        krok_X_plus();
        delay(automaticky_krok);
      }


    // ---------   vyhodnoceni Y osy --------------
    if (osa_Y > 200 and osa_Y < 800)                                     // osa Y neni vychylena
      {
        odblokovano_Y = true;                                            // v teto poloze se odblokuje jeden krok na motoru
      }

    if (osa_Y < 100 and odblokovano_Y == true)                           // naklon joysticku dolu
      {
        krok_Y_minus();
        odblokovano_Y = false;                                           // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                                              // zaznam casu nakloneni
      }

    if (osa_Y < 100 and (millis()-casovac) > 1000)                       // naklon joysticku dolu trva uz dele nez sekundu
      {
        krok_Y_minus();
        delay(automaticky_krok);
      }

    if (osa_Y > 900 and odblokovano_Y == true)                           // naklon joysticku nahoru
      {
        krok_Y_plus();
        odblokovano_Y = false;                                           // po jednom kroku se krokovani zablokuje az do te doby, nez se joystick narovna
        casovac = millis();                                              // zaznam casu nakloneni
      }

    if (osa_Y > 900 and (millis()-casovac) > 1000)                       // naklon joysticku nahoru trva uz dele nez sekundu
      {
        krok_Y_plus();
        delay(automaticky_krok);
      }
  
  }
//-------------- konec hlavni smycky --------------------



//----------------------------------
//  pootoceni motoru v ose X o jeden krok dopredu
void krok_X_plus(void)
  {
    digitalWrite(motor_X_DIR,HIGH);
    digitalWrite(motor_X_STEP,HIGH);
    delay(10);
    digitalWrite(motor_X_STEP,LOW);
    delay(10);    
  }



//----------------------------------
//  pootoceni motoru v ose X o jeden krok dozadu
void krok_X_minus(void)
  {
    digitalWrite(motor_X_DIR,LOW);
    digitalWrite(motor_X_STEP,HIGH);
    delay(10);
    digitalWrite(motor_X_STEP,LOW);
    delay(10);        
  }



//----------------------------------
//  pootoceni motoru v ose Y o jeden krok dopredu
void krok_Y_plus(void)
  {
    digitalWrite(motor_Y_DIR,HIGH);
    digitalWrite(motor_Y_STEP,HIGH);
    delay(10);
    digitalWrite(motor_Y_STEP,LOW);
    delay(10);    
  }



//----------------------------------
//  pootoceni motoru v ose Y o jeden krok dozadu
void krok_Y_minus(void)
  {
    digitalWrite(motor_Y_DIR,LOW);
    digitalWrite(motor_Y_STEP,HIGH);
    delay(10);
    digitalWrite(motor_Y_STEP,LOW);
    delay(10);        
  }

[bernkop]

Dobrý den,

Smekám!!! Moc děkuji za pomoc!! 1. zapojení bylo na arduino mega teď předěláno na uno a funguje perfektně!! Teď ovšem nastává otázka jak tuto sestavu ovládat pomocí dvou arduin uno bezdrátově pomoci (Modul bezdrátový NRF24L01+PA+LNA + Adaptér pro bezdrátový modul NRF24L01) bude se měnit kód a nebo se k němu jen přidá nějaká "komunikační smyčka" ?? v příloze posilám Váš kód který je trochu upraveny jen co se týče rychlostí motoru a serva. A poslední dotaz lze přeprat kód na joystick tak aby měl plynulý chod třeba jako potenciometr?? Moc děkuji!!!

[AstroMiK]

Ten dálkový přenos určitě nějak půjde, ale to přenechám zkušenějším.
Každopádně budeš muset upřesnit, co od toho vlastně očekáváš (Další joystick, který bude umístěný někde na druhém Arduinu?).

Ten plynulý pohyb podle naklonění joysticku by se taky dal nějak upravit.
Jestli teda myslíš jako zrušit krokování při krátkém vychýlení a podle úhlu joysticku krokovat okamžitě různou rychlostí.
V tom případě by to ale bylo na předělání poloviny programu.

[bernkop]

dobrý den,

Ještě jednou moc děkuji za Vaši ochotu a hlavně znalosti které mi moc pomohly!! Mé očekáváváni jsou naprosto jednoduché ovládaní 2x nema 23 + 1x servo. to vše co jsme spolu řešili. jen bych poprosil o tu malou změnu v ovládaní joystick a to by byla změna ne v krokováni ale plynulého chodu.... jestli budete tak moc ochotny a pomůžete mi aspoň s tím kódem na ty motory a joystick budu moc rad a co se tyče bezdrátové komunikace budu řešit dále....

[AstroMiK]

Prosím, poraďte mi někdo s matematikou.
Nějak mi to dneska nemyslí.

Jak mám přemapovat hodnotu joysticku mezi dvě zadané konstanty?

Z obrázku níže snad bude jasné, co mám na mysli.

Předpokládám, že se bude jednat o dvě funkce map().
První bude v prodmínce:

Kód: Vybrat vše

if (joystick < (512 - pasmo_klidu))  rychlost = map ( ????? );

Druhá bude v podmínce:

Kód: Vybrat vše

if (joystick > (512 + pasmo_klidu))  rychlost = map ( ????? );

Mám tam připravené i skutečné krajní hodnoty, které dává joystick při naklonění k úplnému kraji ('min_X' a 'max_X').
A pak samozřejmě konstanty 'rychlost_min' a 'rychlost_max', mezi které se potřebuju s vypočtenou hodnotou 'rychlost' dostat.


EDIT:

Tak už to asi mám.
Když jsem si to nakreslil, tak mi to došlo:

Kód: Vybrat vše

 rychlost = map(joystick   , 512 + pasmo_klidu , max_X , rychlost_min , rychlost_max );

Kód: Vybrat vše

 rychlost = map(joystick   , min_X , 512 - pasmo_klidu , rychlost_max , rychlost_min ); 

joystick.gif (8.02 KiB) Zobrazeno 1226 x

[bernkop]

AstroMIK moc si vážím tvé ochoty!!!